;; SIP009 NFT trait
(impl-trait 'SP2PABAF9FTAJYNFZH93XENAJ8FVY99RRM50D2JG9.nft-trait.nft-trait)
(use-trait commission-trait .commission-trait.commission)
(define-non-fungible-token Project-Indigo-Act1 uint)
;; Storage
(define-map token-count principal uint)
(define-map market uint {price: uint, commission: principal})
;; Constats
(define-constant CONTRACT-OWNER tx-sender)
(define-constant MINT-LIMIT u3000)
;; Errors
(define-constant ERR-SOLD-OUT (err u300))
(define-constant ERR-WRONG-COMMISSION (err u301))
(define-constant ERR-NOT-AUTHORIZED (err u401))
(define-constant ERR-NOT-FOUND (err u404))
(define-constant ERR-METADATA-FROZEN (err u505))
(define-constant ERR-MINT-ALREADY-SET (err u506))
(define-constant ERR-LISTING (err u507))
;; Store the last issued token ID
(define-data-var last-id uint u0)
;; Used to determine if mintpass sale is active
(define-data-var mintpass-sale-active bool false)
;; Used to determine if metadata is frozen
(define-data-var metadata-frozen bool false)
;; Store root token uri to query metadata
(define-data-var base-uri (string-ascii 80) "ipfs://QmUsmdfd6DfLU1Hhi497rBQ8paydQa22dEMik8rRSWDsQf/{id}")
;; Store contract metadata
(define-constant contract-uri "ipfs://QmW5f3JD5gS45rDNQSxxzRK6Y9nf4E1gw6tNFx5VcMzA1f")
;; Store proof hash for images
(define-constant proof-hash "3525fb885e9a6d8bd52e2e3ddb5e350377d5dae6aa64e38f7cf5c22556d9d01f")
;; Store the mint address allowed to trigger minting
(define-map mint-address bool principal)
;; Withdraw wallets
;; Wallet 1 60%
(define-constant WALLET_1 'SP18J677R5GRD7EKK0S096WVQW19SDPWTC0TCBTGV)
;; Wallet 2 40%
(define-constant WALLET_2 'SP2S1JA1G39BAS9C6W48P7TX01ABJCDJ8ETR32T4J)
;; Token count for account
(define-read-only (get-balance (account principal))
(default-to u0
(map-get? token-count account)))
(define-private (trnsfr (id uint) (sender principal) (recipient principal))
(match (nft-transfer? Project-Indigo-Act1 id sender recipient)
success
(let
((sender-balance (get-balance sender))
(recipient-balance (get-balance recipient)))
(map-set token-count
sender
(- sender-balance u1))
(map-set token-count
recipient
(+ recipient-balance u1))
(ok success))
error (err error)))
;; SIP009: Transfer token to a specified principal
(define-public (transfer (id uint) (sender principal) (recipient principal))
(begin
(asserts! (is-eq tx-sender sender) ERR-NOT-AUTHORIZED)
(asserts! (is-none (map-get? market id)) ERR-LISTING)
(trnsfr id sender recipient)))
;; SIP009: Get the owner of the specified token ID
(define-read-only (get-owner (id uint))
(ok (nft-get-owner? Project-Indigo-Act1 id)))
;; SIP009: Get the last token ID
(define-read-only (get-last-token-id)
(ok (var-get last-id)))
;; SIP009: Get the token URI. You can set it to any other URI
(define-read-only (get-token-uri (id uint))
(ok (some (var-get base-uri))))
(define-read-only (get-contract-uri)
(ok contract-uri))
;; Allow contract owner to change the base uri
(define-public (set-base-uri (new-base-uri (string-ascii 80)))
(begin
(asserts! (is-eq tx-sender CONTRACT-OWNER) ERR-NOT-AUTHORIZED)
(asserts! (not (var-get metadata-frozen)) ERR-METADATA-FROZEN)
(var-set base-uri new-base-uri)
(ok true)))
;; Freeze metadata (once frozen, can't be changed)
(define-public (freeze-metadata)
(begin
(asserts! (is-eq tx-sender CONTRACT-OWNER) ERR-NOT-AUTHORIZED)
(var-set metadata-frozen true)
(ok true)))
;; Manage the Mint
(define-private (called-from-mint)
(let ((the-mint
(unwrap! (map-get? mint-address true)
false)))
(is-eq contract-caller the-mint)))
;; Can only be called once
(define-public (set-mint-address)
(let ((the-mint (map-get? mint-address true)))
(asserts! (and (is-none the-mint)
(map-insert mint-address true tx-sender))
ERR-MINT-ALREADY-SET)
(ok tx-sender)))
;; Mint new NFT (Can only be called by mint contract)
(define-public (mint (new-owner principal))
(let ((next-id (+ u1 (var-get last-id))))
(asserts! (called-from-mint) ERR-NOT-AUTHORIZED)
(asserts! (< (var-get last-id) MINT-LIMIT) ERR-SOLD-OUT)
(match (nft-mint? Project-Indigo-Act1 next-id new-owner)
success
(let
((current-balance (get-balance new-owner)))
(begin
(try! (stx-transfer? u42000000 tx-sender WALLET_1))
(try! (stx-transfer? u28000000 tx-sender WALLET_2))
(var-set last-id next-id)
(map-set token-count
new-owner
(+ current-balance u1)
)
(ok true)))
error (err (* error u10000)))))
(define-private (is-sender-owner (id uint))
(let ((owner (unwrap! (nft-get-owner? Project-Indigo-Act1 id) false)))
(or (is-eq tx-sender owner) (is-eq contract-caller owner))))
(define-read-only (get-listing-in-ustx (id uint))
(map-get? market id))
(define-public (list-in-ustx (id uint) (price uint) (comm <commission-trait>))
(let ((listing {price: price, commission: (contract-of comm)}))
(asserts! (is-sender-owner id) ERR-NOT-AUTHORIZED)
(map-set market id listing)
(print (merge listing {a: "list-in-ustx", id: id}))
(ok true)))
(define-public (unlist-in-ustx (id uint))
(begin
(asserts! (is-sender-owner id) ERR-NOT-AUTHORIZED)
(map-delete market id)
(print {a: "unlist-in-ustx", id: id})
(ok true)))
(define-public (buy-in-ustx (id uint) (comm <commission-trait>))
(let ((owner (unwrap! (nft-get-owner? Project-Indigo-Act1 id) ERR-NOT-FOUND))
(listing (unwrap! (map-get? market id) ERR-LISTING))
(price (get price listing)))
(asserts! (is-eq (contract-of comm) (get commission listing)) ERR-WRONG-COMMISSION)
(try! (stx-transfer? price tx-sender owner))
(try! (contract-call? comm pay id price))
(try! (trnsfr id owner tx-sender))
(map-delete market id)
(print {a: "buy-in-ustx", id: id})
(ok true)))